Hàm SUMIF trong Excel

SUMIF. chức năng Là một Hàm Excel giúp bạn tính tổng theo điều kiện cụ thể. Đây là mọi thứ bạn cần biết về Cách sử dụng hàm SUMIF trong Microsoft Excel.

Cách sử dụng hàm SUMIF trong Excel

Hàm SUMIF trong Excel Trả về tổng các ô đáp ứng một điều kiện cụ thể. Bạn có thể áp dụng tiêu chí theo ngày, số và văn bản. Hàm Excel này hỗ trợ các phép toán logic (>, <, <>, =) và các ký tự đại diện để đối sánh từng phần.

• Mục đích: Tính tổng các số trong phạm vi đáp ứng các tiêu chí yêu cầu.
• Giá trị trả về: Tổng các giá trị đã cung cấp.
• Công thức nấu ăn: = SUMIF (phạm vi, tiêu chí, [sum_range]). Trong đó:
  • Phạm vi – Phạm vi áp dụng của tiêu chí.
  • Tiêu chuẩn – Tiêu chí áp dụng.
  • Sum_range – (Tùy chọn) Phạm vi tổng. Nếu bị bỏ qua, các ô trong phạm vi sẽ được thêm vào.
• Phiên bản: Bạn có thể sử dụng Hàm SUMIF trong Excel 2003 trở lên.

Lưu ý khi sử dụng hàm SUMIF trong Microsoft Excel

Như đã nêu trước đó, hàm SUMIF tính tổng các ô trong một phạm vi đáp ứng một điều kiện. Đối số đầu tiên là phạm vi áp dụng tiêu chí, đối số thứ hai là tiêu chí và cuối cùng là phạm vi chứa các giá trị được tổng hợp. SUMIF hỗ trợ các toán tử logic, các ký tự đại diện để đối sánh từng phần. Tiêu chí có thể sử dụng một giá trị trong một ô khác.

SUMIF nằm trong nhóm 8 hàm trong Excel, chia tiêu chí logic thành 2 phần (phạm vi + tiêu chí). Do đó, công thức được sử dụng để xây dựng tiêu chí sẽ khác và SUMIF cần một phạm vi ô cho đối số phạm vi, bạn không thể sử dụng một mảng.

SUMIF chỉ hỗ trợ một điều kiện duy nhất. Nếu cần áp dụng nhiều tiêu chí, hãy sử dụng hàm SUMIFS.

Ví dụ về cách sử dụng hàm SUMIF trong Excel

Bảng tính

Trong trang tính ví dụ trong bài viết này, có 3 công thức SUMIF. Trong công thức đầu tiên (G5), SUMIF trả về tổng doanh số của Jim. Trong cột thứ hai (G6), SUMIF trả về tổng doanh số bán hàng ở bang CA (California). Trong công thức thứ 3 (G7), SUMIF trả về tổng doanh số> 100.

=SUMIF(B5:B15,"jim",D5:D15) // name = "jim"
=SUMIF(C5:C15,"ca",D5:D15) // state = "ca"
=SUMIF(D5:D15,">100") // sales > 100

Lưu ý, bạn không cần dấu bằng khi xây dựng tiêu chí “bằng nhau”. Ngoài ra, lưu ý rằng SUMIF không phân biệt chữ hoa chữ thường, vì vậy bạn có thể sử dụng jim hoặc jim. Cuối cùng, hãy nhớ rằng công thức cuối cùng không bao gồm sum_range, vì vậy phạm vi.

Tiêu chí trong một hộp khác

Giá trị từ các ô khác có thể được đưa vào tiêu chí bằng cách sử dụng một phép nối. Trong ví dụ dưới đây, SUMIF tính toán tổng doanh số và kết quả trong ô G4. Các số lớn hơn (>) là văn bản phải được đặt trong dấu ngoặc kép. Công thức trong G5 là:

=SUMIF(D5:D9,">"&G4) // tính tổng nếu lớn hơn G4

Không ngang hàng

Để thể hiện các tiêu chí không bằng nhau, hãy sử dụng toán tử <> trong dấu ngoặc kép (“”):

=SUMIF(B5:B9,"<>red",C5:C9) // không bằng với "red"
=SUMIF(B5:B9,"<>blue",C5:C9) // không bằng với "blue"
=SUMIF(B5:B9,"<>"&E7,C5:C9) //  không bằng với E7

Ô trống

SUMIF có thể tính tổng dựa trên các ô trống hoặc không trống. Trong ví dụ dưới đây, SUMIF được sử dụng để tính tổng số tiền trong cột C tùy thuộc vào cột D chứa x hoặc để trống.

=SUMIF(D5:D9,"",C5:C9) // blank
=SUMIF(D5:D9,"<>",C5:C9) // not blank

Ngày

Cách tốt nhất để sử dụng SUMIF. chức năng chứa một ngày là một tham chiếu đến một ngày hợp lệ trong một ô khác hoặc sử dụng hàm DATE. Ví dụ dưới đây cho thấy cả hai phương pháp:

=SUMIF(B5:B9,"<"&DATE(2019,3,1),C5:C9)
=SUMIF(B5:B9,">="&DATE(2019,4,1),C5:C9)
=SUMIF(B5:B9,">"&E9,C5:C9)

Lưu ý, bạn phải nối một toán tử với ngày ở E9. Để sử dụng tiêu chí ngày nâng cao hơn, bạn nên sử dụng hàm SUMIFS.

Nhân vật đại diện

Hàm SUMIF trong Excel hỗ trợ các ký tự đại diện như ví dụ bên dưới:

=SUMIF(B5:B9,"mi*",C5:C9) // bắt đầu bằng "mi"
=SUMIF(B5:B9,"*ota",C5:C9) //kết thúc bằng "ota"
=SUMIF(B5:B9,"????",C5:C9) // chứa 4 ký tự

Tóm lại, những điều bạn cần biết khi sử dụng hàm SUMIF trong Excel:

• SUMIF chỉ có 1 điều kiện được hỗ trợ. Sử dụng hàm SUMIFS cho nhiều tiêu chí.
• Khi nào sum_range bỏ qua, ô trong phạm vi sẽ được tính.
• Chuỗi văn bản tiêu chí phải được đặt trong (“”), ví dụ: “apple”, “> 32”, “ja *”
• Tham chiếu ô dựa trên tiêu chí không được bao gồm trong dấu ngoặc kép, ví dụ: “<" & A1
• Ký tự đại diện ? và * có thể được sử dụng theo các tiêu chí. Dấu chấm hỏi khớp với ký tự bất kỳ, dấu sao khớp với chuỗi ký tự.
• Để tìm dấu chấm hỏi hoặc dấu hoa thị, hãy sử dụng dấu ngã (~) trước dấu chấm hỏi hoặc dấu hoa thị (ví dụ: ~ ?, ~ *).